;
; A MTX512 S2 has 256KB DRAM and a PAL which makes 64KB or more available
; in RELCPMH=0 mode, and 208KB available in RELCPMH=1 mode.
;
; Because NA15 isn't remapped as it is in MTX500 and MTX512, the delta page
; isn't backed by the same DRAM when seen in different RELCPMH modes.
; The delta page anomoly cannot be addressed, given the yellow wiring.
;

TITLE MTX with 16KB+8KB ROM and 64KB/208KB RAM for MTX512 S2
PATTERN A
REVISION 1.0
AUTHOR ANDY KEY
COMPANY NYANGAU.ORG
DATE 11/8/14

CHIP 2_208 GAL16V8

	A13 A14 A15 P2 R1 R2 P1 MREQL RDL GND
	MPX P0 RELCPMH RAM MA8 CE64 CEA P3 R0 VCC

EQUATIONS

	/CEA  = /RELCPMH                   * /A15 * /A14 * /A13 * /MREQL * /RDL
	      + /RELCPMH * /R2 * /R1 * /R0 * /A15 * /A14 *  A13 * /MREQL * /RDL
	/CE64 = /RELCPMH * /R2 * /R1 *  R0 * /A15 * /A14 *  A13 * /MREQL * /RDL
	      + /RELCPMH *  R2 *  R1 *  R0 * /A15 * /A14 *  A13 * /MREQL * /RDL

	/MA8  = A15 * A14
	      +  P0 *  MPX
	      + /P1 * /MPX

	/RAM  =                                     A15 *  A14 * /MREQL
	      +  RELCPMH * /P3 * /P2                           * /MREQL
	      + /RELCPMH * /P3 * /P2 * /P1 * /P0 * /A15 *  A14 * /MREQL
	      + /RELCPMH * /P3 * /P2 * /P1       *  A15 * /A14 * /MREQL